Graphic method in vb net(A)

2018年12月02日

第二十一章VB .NET繪圖物件及方法介紹(上)

21.1前言

要如何利用VB .NET所提供之工具繪製圖形呢？相信很多人從VB 6.0升級到V B.NET版本後，會覺得VB .NET似乎變得複雜及困難些？尤其是繪圖方面更是如此。此可能與VB .NET不再提供繪圖物件或控制項的AutoRedraw

、ScaleMode、Scale、DrawMode等屬性及圖案方塊(PictureBox)吸取顏色的Point()及指定顏色畫點Pset()等方法多少有些關係。下面我們就為VB .NET繪圖物件與繪圖方法作簡要的說明，其他與繪圖整合設計觀念有關者如ScaleMode、Scale等則會另章討論。一般而言，在VB .NET作業環境下畫圖，除控制項有Paint event hander者外，多需先建立繪圖物件(Graphics)作為畫圖區域，然後定義一個筆刷(Brush)或(和)畫筆(Pen)，以填充圖形內部區域及外框。

21.2畫圖結構

VB .NET的System.Drawing名字空間內，定義了四種常用的結構(Stucture)型態：(1)顏色(Color)，(2)點(Point)，(3)尺寸(Size)，(4)矩形(Rectangle)。

結構(Structure)	說明
Color	ARGB(alpha,red,green,blue)，代表色彩透明度alpha值及色彩的R.G.B值。
Point	表示整數X和Y座標的排序配對，這個配對值，用來定義二維平面的點位置。
Size	儲存已排序的整數配對，通常是矩形的寬度和高度。
Rectangle	儲存四個為一組的整數，表示矩形位置和大小。如需更多進階的區域函式，請使用 System.Drawing.Region 物件。

21.2.1 顏色結構

常用選擇顏色的方法有(1)color.Colorname，(2)Color.FromRGB()，

(3)ColorTrans.FromOle()，(4)Color.FromName()，(5)ColorTranslator

.FromWin32()等。

21.2.1.1系統預設顏色

使用系統預設Color結構可以直接設定：
例如將Button1背景顏色設定成藍色，可寫成：

Button1.BackColor=Color.Blue

要將Label1前景色設定為紅色，可寫成：

Label1.ForeColor=Color.Red

如果要設定其他顏色，要如何設定呢？Microsoft MSDN官方網站列舉了很多種顏色如下表可供User使用。例如想要設定使用淺灰色及灰色可以寫成Color.LightGray或深灰色Color.DarkGray；粉紅色就寫成Color.Magenta，深紅色寫成Color.DeepPink。

下面為寫出VB .NET提供的所有預設顏色片段程式碼，供讀者參考。

Private Sub FrmCollections_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

Dim colorNames As New System.Collections.Generic.List(Of String)

For Each known As KnownColor In [Enum].GetValues(GetType(KnownColor))

'從列舉預設顏色陣列清單中取出顏色物件

Dim specific As Color = Color.FromKnownColor(known) '

If Not specific.IsSystemColor Then

colorNames.Add(known.ToString())

End If

Next known

colorNames.Sort() '排序

For Each colorName As String In colorNames

ListBox1.Items.Add(colorName) '寫出顏色到ListBox1

Next colorName

End Sub

Private Sub ListBox1_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ListBox1.SelectedIndexChanged '從ListBox1選取顏色

Dim st1 As String

st1 = ListBox1.SelectedItem.ToString

Dim col1 As Color

col1 = Color.FromName(LblColor.Text)

Dim st2 As String = GetHexColor(col1)

LblColor.Text = st1

PicColorShow.BackColor = Color.FromName(st1) '顯示顏色

End Sub

Private Sub ListBox1_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ListBox1.SelectedIndexChanged ‘選取顏色

Dim st1 As String

st1 = ListBox1.SelectedItem.ToString

Dim col1 As Color

col1 = Color.FromName(LblColor.Text)

Dim st2 As String = GetHexColor(col1)

LblColor.Text = st1

PicColorShow.BackColor = Color.FromName(st1)

End Sub

(取材自http://www.happyvb.twbbs.org/wp-content/uploads/2010/03/Color.png)

21.2.1.2 RGB三原色

如果要以RGB(Red,Green,Blue)三原色來設定色彩，可使用Color.FromArgb方法，語法：

Color.FromArgb(R,G,B)

R、G、B的範圍是0~255的整數，因此利用此方法可設定多達256*256*256=

1677,7216種顏色。下表為較種常用顏色的RGB值：

顏色	R	G	B
紅(Red)	255	0	0
綠(Green)	0	128	0
淺藍(LightBlue)	0	255	255
藍(Blue)	0	0	255
黃(Yellow)	255	255	0
紫(Violet)	128	0	128
黑(Black)	0	0	0
白(White)	255	255	255

如要設定表單背景顏色為綠色，可寫成：

Me.BackColor=Color.FromArgb(0,128,0)

指令按鈕單背景顏色為淺藍色，可寫成：

Button1.BackColor=Color.FromArgb(0,255,255)

21.2.1.3 ColorTranslator.FromOle方法

如果要使用VB 6.0的QBColor()顏色表示法，可使用ColorTranslator.FromOle方法。VB 6.04的QBColor有16種顏色(0~15)，有關QBColor()顏色值可參考下表：

顏色	代碼	顏色	代碼
黑(Black)	0	灰(Gray)	8
藍(Blue)	1	淺藍(Light Blue)	9
綠(Green)	2	淺綠(Light Green)	10
青(Cyan)	3	淺藍(Light Cyan)	11
紅(Red)	4	淺紅(Light Red)	12
粉紅(Magenta)	5	淺粉紅(Light Magenta)	13
黃(Yellow)	6	淺黃(Light Yellow)	14
白(White)	7	亮白(Bright White)	15

使用語法為：

ColorTranslator.FromOle(QBColor(顏色值代碼))

例如要將表單背景顯示成紅色，可寫成：

Me.BackColor = ColorTranslator.FromOle(QBColor(12))

21.2.1.4 Color.FromName()

Color.FromName()使用語法為：

Color.FromName("顏色名稱")

例如要將標籤背景顯示成紅色，可寫成：

LblColorShow.BackColor = Color.FromName("red")

21.2.1.5 ColorTranslator.FromWin32()

VB .NET也支援以十六進位來表示顏色值，我們可以使用ColorTranslator.FromWin32方法，並在十六進位值前面加上&H即可。

使用語法為：

ColorTranslator.FromWin32(&H十六進位值)

例如將標籤控制項的背景改成紅色，可寫成：

Label1.BackColor = ColorTranslator.FromWin32(＆HFF0000)

21.2.2 點結構

點(Point)主要在定義點的位置，如不使用點結構，則必須使用兩個數字(整數或浮點數)來規範點的位置。其使用語法為：

Dim Pt1 As Point =New(20,30) ‘整數型態

Dim Pt2 As PointF =New(20F,30F) ‘浮點數型態

或

Dim Pt1 As Point

Pt1=New(20,30) ‘整數型態

Dim Pt2 As PointF

Pt2 =New(20F,30F) ‘浮點數型態

或

Dim Pt1 As Point

Pt1.x= 20 ‘整數型態

Pt1.y= 30 ‘整數型態

Dim Pt2 As Point

Pt2.x = 20F ‘浮點數型態

Pt2.y = 30F ‘浮點數型態

21.2.3 尺寸結構

尺寸(Size)主要在定義物件的寬、長尺寸，尺寸結構可為整數或浮點數兩種。其使用語法為：

Dim Size1 As Size =New(20,30) ‘整數型態

Dim Size2 As SizeF =New(20F,30F) ‘浮點數型態

或

Dim Size1 As Size

Size1=New(20,30) ‘整數型態

Dim Size1 As SizeF

Size2 =New(20F,30F) ‘浮點數型態

21.2.4 矩形結構

矩形結構(Rectangle)結合點及寬長尺寸的資料結構，其可為整數或浮點數兩種。其使用語法為：

Dim Rect1 As Rectangle =New(2,2,20,30) ‘整數型態

Dim Rect2 As RectangleF =New(2F,2F,20F,30F) ‘浮點數型態

或

Dim Rect1 As Rectangle

Rect1=New(2,2,20,30) ‘整數型態

Dim Rect1 As RectangleF

Rect2 =New(2F,2F,20F,30F) ‘浮點數型態

上述”2,2”或” 2F,2F”為矩形起點；”20,30”或” 20F,30F”為矩形寬、高。

21.3筆刷、畫筆及路徑

筆刷(Brush)及畫筆(Pen)是VB .NET中除畫圖區域以外，兩種非常重要的畫圖類別。筆刷是用單色、圖紋、圖片、漸變色彩等來填充塗抹、鋪貼一個封閉區域。畫筆則用來描繪直線、曲線或封閉區域的外觀。如要同時用筆刷及畫筆畫同一個範圍，原則上應先用筆刷再用畫筆，否則畫筆可能會被筆刷掩蓋部份外框線條。

21.3.1筆刷

筆刷(Brush)一般多與畫圖方法如FillEllipse、FillPath、FillPolygon、FillRectanle

、FillRectanles配合使用。筆刷有實心筆刷(SolidBrush)、紋理筆刷(TextureBrush)、圖紋筆刷(HatchBrush)、線性色彩漸變筆刷(LinearGradientBrush)、路徑色彩漸變筆刷(PathGradientBrush)等。

(1)實心筆刷

實心筆刷為單色筆刷，定義SolidBrush語法為：

Dim myBrush As New SolidBrush(Color.Colorname)

上述中Colorname可以任意預設系統色彩如：Color.Red、Color.Blue、Color.Black、Color.Gray等等。

(2)紋理筆刷

紋理筆刷一般多以BitMap圖片為封閉區域鋪貼圖案，使用TextureBrush語法為：

Dim myBrush As New TextureBrush(PicTure.Image)

上述中PicTure.Image圖片名程。

(3)圖紋筆刷

圖紋筆刷為利用點、線、形狀等簡單圖案填貼封閉區域者。

使用HatchBrush語法為：

Dim myBrush As New HatchBrush(HatchStyle.DiagonalCross, ForeColor, BackColr)

上述中ForeColor 為前景顏色，BackColr 為背景顏色，背景顏色可以省略。

VB .NET所提供的圖紋筆刷圖案如下列所示：

(4)線性色彩漸變筆刷

色彩漸變一般是兩種或兩種以上顏色以線性漸變方式變化的筆刷，為封閉區域上色者。

Dim Rect As New Rectangle(40, 40, 150, 180) '矩形漸層

Dim lBrush As New LinearGradientBrush(Rect, Color1, Color2, LinearGradientMode.Horizontal) '漸層筆刷

上述中Color1 為第一種顏色，Color2 為第二種顏色，LinearGradientMode.Horizontal為線性漸變模式，以本例而言，漸變模式為水平方向。

(5)路徑色彩漸變筆刷

路徑色彩漸變筆刷，為以某點為中心的顏色(如黃色)依某路徑向外依線性漸變顏色(外層為藍色及黑色)，為封閉區域上色者。下面為路徑色彩漸變筆刷及繪畫方法程式片段。

Dim Gr As Graphics = Me.CreateGraphics '以表單為繪圖物件(繪圖區)

Dim myPath As New GraphicsPath

Dim myRect As New Rectangle(50, 40, 140, 150) ‘路徑以矩陣為準

myPath.AddRectangle(myRect)

Dim myPGBrush As New PathGradientBrush(myPath)

myPGBrush.CenterColor = Color.Yellow ‘中心顏色

Dim Colors As Color() = {Color.Magenta, Color.Blue, Color.Black} '周圍顏色可以多色

myPGBrush.SurroundColors = Colors

Gr.FillPath(myPGBrush, myPath)

Dim Gp As Graphics = PictureBox1.CreateGraphics

Gp.FillPath(myPGBrush, myPath)

21.3.2畫筆

畫筆物件為決定線條顏色(Color)、厚度(Thickness)、虛實線(Dash style)、線段結合(Joint style)、端點式樣(End cap style)。畫筆物件可以使用預定的280種中畫筆(如Pens.Red、PensBlue、PensBlack…….)，預設畫筆筆寬為1單位的實線，如因為陣列運算致筆厚小於1或等於0，則系統仍採用1。User可以New關鍵字來建立畫筆。其用語為如：

同時設定筆色及寬度者

Dim Pen1 as new Pen(Color.Red,2)

或

Dim Pen1 as new Pen(Color.Red)

Pen1.Width=2

如需要另規範畫筆式樣，可以定義類似如下：

Pen1.DashStyle = DashStyle.Dash

如需要另規範畫筆端點，則可以另定義類似如：

Pen1.EndCap = LineCap.DiamondAnchor

21.3.畫圖路徑

畫圖路徑(GraphicsPath)物件代表以直線、曲線、文字、其他指令或包含其他畫圖路徑的物件。GraphicsPath可配合AddLine、AddEllipse、AddRectangle、AddRectangles、 AddCurve 、AddBezier、AddBeziers、AddPath、…等繪製路徑方法一齊使用。

下面的程式片段，為使用AddLine及AddLines的例子。

Dim path1, path2 As New GraphicsPath

Dim tpen As New Pen(Color.Magenta, 6) '畫筆

Dim tbrush As Brush = Brushes.Green '筆刷

Dim gp As Graphics = PictureBox1.CreateGraphics

path1.AddLine(150, 150, 250, 250)

gp.DrawPath(tpen, path1)

Dim pts(2) As PointF

pts(0).X = 150

pts(0).Y = 160

pts(1).X = 250

pts(1).Y = 260

pts(2).X = 380

pts(2).Y = 290

path2.AddLines(pts)

gp.DrawPath(tpen, path2)

下面的程式片段，為使用AddEllipse的例子。

Dim path1, path2 As New GraphicsPath

Dim tpen As New Pen(Color.Magenta, 6) '畫筆

Dim tbrush As Brush = Brushes.Green '筆刷

Dim gp As Graphics = PictureBox1.CreateGraphics

path1.AddEllipse(150, 150, 150, 150)

path2.AddEllipse(180, 180, 100, 100)

gp.DrawPath(tpen, path1) '空心

gp.FillPath(tbrush, path2) '填滿

21.4 畫圖方法

21.4.1Obj.CreateGraphics

如果想在Form(表單)、PictureBox(圖形控制項)、或印表機(PrintDocunt)、圖片(Bitmap)等控制項上繪圖，可利用CreateGraphics方法。步驟如下：
(1)建立Graphics繪圖物件：

先宣告一個繪圖(Graphics)物件，作為畫圖的區域(類似畫布或畫紙)，並設定繪圖物件等於控制項的CreateGraphics方法，如此才能在該控制項上繪圖。

一般宣告繪圖Graphics物件的方式有下列幾種：

(a) Dim gr as Graphics=Me.CreateGraphics ‘以Form為畫布

(b) Dim gp as Graphics=Me.PictureBox1.CreateGraphics ‘以PictureBox為畫布

Dim gb as Graphics=Graphics.FromImage(bmp) ‘在bmp上畫圖

(d) Dim img as New Image=System.Drawing.Image.FromFile(“c:\Tpt\Test.jpg”)

‘載入c:\Tpt\Test.jpg 圖檔

Dim gi as Graphics=Graphics.FromImage(img) ‘在c:\Tpt\Test.jpg上畫圖

(2)定義筆刷物件：

建立定義筆刷物件，並指定筆刷的顏色(Color結構)或圖案紋路式樣等，此定義完成的筆刷供步驟(4)使用

(3)定義Pen畫筆物件：

建立定義畫筆物件，並指定畫筆的顏色(Color結構)、線條寬度、線條式樣(虛、實線)、端節點樣式等，定義完成的畫圖物件將提供步驟(4)使用。

(4)定義Graphics的方法：

依畫圖樣式不同，如直線、橢(圓)、矩(方)、橢圓(圓)弧…等，來呼叫Graphics類別的DrawLine、DrawLines、DrawEllipse、DrawRectangle、DrawArc、DrawPie、DrawCurve、DrawClosedCurve、…等不同方法。前述各方法大同小異，因此本節僅介紹其中幾種，其餘請參考附錄的程式碼。

(4)畫完圖後，必要時應拋棄釋放Graphics繪圖物件。

為方便讀者熟悉表單及PictureBox繪圖方式之差異，我們所採用的片段程式碼，多採用兩者合併方式呈現。

'表單畫線

Dim gr As Graphics

gr = Me.CreateGraphics '宣告 gr畫圖物件

Dim myPen1 As Pen = New Pen(Color.Red) '宣告 myPen1畫筆圖物件

gr.DrawLine(myPen1, 58, 60, 130, 120) '使用畫線方法

'圖形方塊畫線

Dim gp As Graphics

gp = PictureBox1.CreateGraphics '宣告 gp畫圖物件

Dim myPen2 As Pen = New Pen(Color.Red) '宣告 myPen畫筆圖物件

gp.DrawLine(myPen2, 58, 60, 130, 120) '使用畫線方法

上述程序碼中gr是以表單為畫圖物件；gp是以PictureBox為畫圖物件。預設筆寬為1，如筆寬取小於1或等於0，則系統會自動改用1。上述程序碼，如改以點結構表示，且筆寬為2 Pixels，樣式為虛線，可以改寫成：

Dim gr As Graphics

gr = Me.CreateGraphics '宣告 gp畫圖物件

Dim myPen1 As Pen = New Pen(Color.Red) '宣告 myPen畫筆圖物件

myPen1.Width=2 ‘筆寬

myPen2.DashStyle = DashStyle.Dash ‘線條樣式

gr.DrawLine(myPen1, New point(58, 60), New(130, 120) ) '使用畫線方法

或

Dim pt1 As New Point(58,60)

Dim Pt2 As New point(130,120)

myPen2.DashStyle = DashStyle.Dash

gr.DrawLine(New Pen(Color.Red,2), pt1,pt2 ) '比筆寬2

下面我們再舉一個畫曲線例子：

Dim tpen As New Pen(Color.Magenta, 2) '畫筆

Dim gp As Graphics = PictureBox1.CreateGraphics

Dim pts(4) As PointF

pts(0).X = 50

pts(0).Y = 60

pts(1).X = 150

pts(1).Y = 160

pts(2).X = 280

pts(2).Y = 190

pts(3).X = 90

pts(3).Y = 120

pts(4).X = 80

pts(4).Y = 90

gp.DrawCurve(tpen, pts)

Dim gr As Graphics = CreateGraphics()

gr.DrawCurve(tpen, pts)

上述程式碼如將DrawCurve改為gr.DrawClosedCurve(tpen, pts)，則所繪製曲線就變成

閉合曲線。VB .NET所提供的曲線與真正的Spline曲線並不十分吻合。

下面為繪製DrawString的程式碼及執行後成果畫面。

Dim gr As Graphics = Me.CreateGraphics

Dim gp As Graphics = PictureBox1.CreateGraphics

Dim mybrush As Brush = Brushes.Orange

Dim myfont As Font = New Font("新明細圖", 50)

gr.DrawString("新年快樂", myfont, mybrush, 5, 4

gp.DrawString("新年快樂", myfont, mybrush, 5, 45)

21.4.2 Paint事件繪圖

除了利用控制項的CreateGraphics方法來繪圖外，也可以利用控制項的Paint事件。

Paint事件e為 System.Windows.Forms.PaintEventArgs的引數，其可直接用來作為表單或PictureBox繪圖，因為其被宣告為PaintEventArgs類別，只要有存取PaintEventArgs類別的Graphics屬性，即可繪圖。繪完圖後也不必使用Dispose()釋放畫筆或筆刷。將畫圖方法寫在Form1_Paint()或PictureBox1_Paint程式中，兩者除Sub名稱不同外，內容相同，在表單或PictureBox被遮蓋或放大縮小時都會自動重繪(與VB 6.0中設定AutoRedraw=True)相當。

Private Sub Form1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint

Dim myPen1 As Pen = New Pen(Color.Red) '宣告 myPen畫筆圖物件

myPen1.Width=2 ‘筆寬

myPen2.DashStyle = DashStyle.Dash ‘線條樣式

e.graphics.DrawLine(myPen1, New point(58, 60), New Point(130, 120) ) '使用畫線方法

或

Private Sub PictureBox1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles PictureBox1.Paint

Dim myPen1 As Pen = New Pen(Color.Red) '宣告 myPen畫筆圖物件

myPen1.Width=2 ‘筆寬

myPen2.DashStyle = DashStyle.Dash ‘線條樣式

e.graphics.DrawLine(myPen1, New point(58, 60), New Point(130, 120) ) '使用畫線方法

End Sub

21.4.3繪製區域

區域(Region)如果要製作比較複雜的圖形，可使用區域(Region)物件，搭配其聯集(Union)、交集(Intersect)、未重疊(Xor)、除外(Exclude)、…等方法，來製作多種幾何的圖形。下面為區域1(矩形)及區域2(橢圓形)兩交集區域之程式碼及成果畫面。

Dim Path1, Path2 As New GraphicsPath

Dim Region1, Region2 As Region

Dim gr As Graphics = Me.CreateGraphics

Dim gp As Graphics

gp = PictureBox1.CreateGraphics

Dim rect1 As Rectangle = New Rectangle(150, 150, 100, 100)

gr.DrawRectangle(Pens.Red, rect1)

gp.DrawRectangle(Pens.Red, rect1)

Path1.AddRectangle(New Rectangle(150, 150, 100, 150)) '矩形

Path2.AddEllipse(150, 150, 130, 70) '橢圓形

gp.DrawEllipse(Pens.Green, 150, 150, 130, 70) '橢圓形

region1 = New Region(path1)

region2 = New Region(path2)

'著要設定兩區域重疊顯示方法。將紅色繪圖顯示於表單中，寫成：

Dim tbrush As Brush = Brushes.Blue '產生藍色筆刷

Region2.Intersect(Region1)

gr.FillRegion(tbrush, Region2)

gp.FillRegion(tbrush, Region2)

下面為為區域2(橢圓形)及區域1(矩形)兩區域經過Xor運算，區域2剩餘區域之程

式碼及成果畫面。其餘區域運算程式碼寫法多大同小異，請參考附錄之程序碼。

Dim Path1, Path2 As New GraphicsPath

Dim Region1, Region2 As Region

Dim Gr As Graphics = Me.CreateGraphics '以表單為繪圖物件(繪圖區)

Dim gp As Graphics

gp = PictureBox1.CreateGraphics

Dim rect1 As Rectangle = New Rectangle(150, 150, 100, 100)

Gr.DrawRectangle(Pens.Red, rect1)

gp.DrawRectangle(Pens.Red, rect1)

Path1.AddRectangle(New Rectangle(150, 150, 100, 150)) '矩形

Path2.AddEllipse(150, 150, 130, 70) '橢圓形

Gr.DrawEllipse(Pens.Green, 150, 150, 130, 70) '橢圓形

gp.DrawEllipse(Pens.Green, 150, 150, 130, 70) '橢圓形

Region1 = New Region(Path1)

Region2 = New Region(Path2)

'著要設定兩區域重疊顯示方法。將紅色繪圖顯示於表單中，寫成：

Dim tbrush As Brush = Brushes.Blue '產生藍色筆刷

Region2.Xor(Region1)

Gr.FillRegion(tbrush, Region2)

gp.FillRegion(tbrush, Region2)

21.4.繪製字串路徑

繪製字串(DrawString)方所使用到的引數較多，使用上似乎比較麻煩些，前面我們曾介紹一般字串的程序碼寫法，此處我另介紹字串路徑(空心字串)的程式碼寫法：

下面則為DrawPath(String) 的程式碼及執行後成果畫面。

Dim gr As Graphics = Me.CreateGraphics

Dim gp As Graphics = PictureBox1.CreateGraphics

Dim txt As String = "VB" '空心字體

Dim filename As String

If dlgOpenDigFile.ShowDialog() = DialogResult.OK Then '載入填充空心字體的圖檔

filename = dlgOpenDigFile.FileName

End If

'載入點陣圖

Dim myBmp As New Bitmap(filename)

Using graphics_path As New GraphicsPath() '使用graphicsPath類別

graphics_path.AddString(txt, _ '加入字串

New FontFamily("Times New Roman"), _ '使用"Times New Roman"字體

FontStyle.Bold, 200, _ '字體樣式,尺寸

New Point(0, 140), _ '字體開始位置

New StringFormat) '字體格式

Using tBrush As New TextureBrush(myBmp) '利用紋理筆刷

gr.FillPath(tBrush, graphics_path) '以tBrush貼舖路徑內部

gp.FillPath(tBrush, graphics_path)

End Using

gr.DrawPath(Pens.Red, graphics_path) '填充路徑外框

gp.DrawPath(Pens.Red, graphics_path)

End Using

下面為字串旋轉之程序碼寫法旋轉135°後成果畫面。

Dim gr As Graphics = Me.CreateGraphics

Dim gp As Graphics = PictureBox1.CreateGraphics

Dim rect_wid As Integer = Me.ClientSize.Width - 760 ' 字串外框寬

Dim rect_hgt As Integer = Me.ClientSize.Height - 360 ' 字串外框高

Dim layout_rect As New RectangleF( _

(Me.ClientSize.Width - rect_wid) \ 4, _

(Me.ClientSize.Height - rect_hgt) \ 4, _

rect_wid, rect_hgt)

'定義字串及字體.

Dim txt As String = "您好!"

Using the_font As New Font("細明體", 60, FontStyle.Bold, GraphicsUnit.Pixel)

Dim tAng As Single = InputBox("請輸入旋轉角度(Deg)", "旋轉角度", "30") ‘輸入旋轉角度

' 設定文字對齊格式.

Using string_format As New StringFormat

string_format.Alignment = StringAlignment.Center

string_format.LineAlignment = StringAlignment.Center

' 平移(-ClientSize.Width \ 4,-Me.ClientSize.Height \ 4),旋轉tAng度,後移回.

gr.TranslateTransform(-Me.ClientSize.Width \ 4, -Me.ClientSize.Height \ 4, MatrixOrder.Append)

gr.RotateTransform(tAng, MatrixOrder.Append)

gr.TranslateTransform(Me.ClientSize.Width \ 4, Me.ClientSize.Height \ 4, MatrixOrder.Append)

' 繪製文字及外框.

gr.TextRenderingHint = System.Drawing.Text.TextRenderingHint.AntiAliasGridFit

gr.DrawString(txt, the_font, Brushes.Blue, layout_rect, string_format)

gr.DrawRectangle(Pens.Magenta, Rectangle.Round(layout_rect))

' 平移(-ClientSize.Width \ 4,-Me.ClientSize.Height \ 4),旋轉tAng度,後移回.

gp.TranslateTransform(-Me.ClientSize.Width \ 4, -Me.ClientSize.Height \ 4, MatrixOrder.Append)

gp.RotateTransform(tAng, MatrixOrder.Append)

gp.TranslateTransform(Me.ClientSize.Width \ 4, Me.ClientSize.Height \ 4, MatrixOrder.Append)

' ' 繪製文字及外框.

gp.TextRenderingHint = System.Drawing.Text.TextRenderingHint.AntiAliasGridFit

gp.DrawString(txt, the_font, Brushes.Green, layout_rect, string_format)

gp.DrawRectangle(Pens.Blue, Rectangle.Round(layout_rect))

End Using

上述程序碼中要使用到TranslateTransform()與RotateTransform()，有關此部份之解說，我們會後面節另外說明。

21.5 影像處理

影像處理(Image processing)的Image，是一個比較抽象的類別，因其屬抽象類別必須藉由其衍生類別如點陣圖(Bitmap)或向量圖(MetaFile)物件實作。不論是點陣圖或向量圖都屬處理資料結構較低層次的物件，點陣圖物件以擷取諸如DrawLine、DrawEllipse畫圖方法中像素資料在表單或圖形方塊顯示圖形或儲存成檔案資料(儲存相素資料)；而向量圖則擷取畫圖資料變成可以隨時可以在畫圖區域再次顯示之向量圖資料(儲存畫圖指令)。

21.5.1影像

影像(Image)為繪製、複製、轉換、物件及展示用圖片(Picture)，其屬抽象類別，必須透過其衍生類別如點陣圖(Bitmap)或向量圖(MetaFile)物件以建立實體物件。

如下面片段程式就是建立點陣圖的例子：

Dim bmp As New Bitmap(200, 200)

Using gr As Graphics = Graphics.FromImage(bmp)

gr.DrawEllipse(Pens.Blue, 20, 20, 120, 160)

End Using

21.5.2點陣圖

點陣圖(Bitmap)是以像素資料定義的類別，User可以用這些資料運算、修正、儲存圖像等處理作業，這些資料可以在表單、圖形方塊、控制項顯示，點陣圖可轉存為Bmp、Gif、Jpeg、Png、Tiff等類型檔案。點陣圖很多重要的屬性、方法多是繼承自Image抽象類別。

(1) 儲存圖檔：

點陣圖可以以物件儲存成檔案，點陣圖儲存預設檔案格式為Png格式，因此如儲存成Png檔只需要輸入檔名，其餘格式則應另輸入格式名稱。下面之程式碼為先在表單上畫圖後，再利用檔案儲存對話方塊(SaveFileDialog)中輸入欲儲存的圖檔名稱(***)，分別儲存成***.bmp、***.jpg、***.gif格式圖檔。

'建立如圖形方塊Picturebox1大小的點陣圖物件

Dim Filename As String

Dim myBmp As New Bitmap(PictureBox1.Width, PictureBox1.Height)

' 建立繪圖物件.

Dim gr As Graphics = Graphics.FromImage(myBmp)

' 在繪圖物件上繪圖.

gr.FillRectangle( _

New SolidBrush(Color.LightGreen), _

0, 0, Me.ClientSize.Width, Me.ClientSize.Height)

'建立矩形物件

Dim rect As New Rectangle(5, 5, _

myBmp.Width - 10, myBmp.Height - 10)

gr.FillEllipse( _

New HatchBrush(HatchStyle.LightDownwardDiagonal, _

Color.Black, Color.Yellow), _

rect)

gr.DrawEllipse(New Pen(Color.Blue, 3), rect)

' 顯示結果.

PictureBox1.Image = myBmp

myBmp = PictureBox1.Image

If dlgSaveDigFile.ShowDialog() = DialogResult.OK Then

Filename = dlgSaveDigFile.FileName

End If

' 儲存成bitmap, JPEG, GIF格式.

myBmp.Save(Filename & ".bmp", System.Drawing.Imaging.ImageFormat.Bmp)

myBmp.Save(Filename & ".jpg", System.Drawing.Imaging.ImageFormat.Jpeg)

myBmp.Save(Filename & ".gif", System.Drawing.Imaging.ImageFormat.Gif)

MsgBox("Ok")

(2)載入圖檔：

載入圖檔與儲存圖檔作業方式類似，可以利用檔案開啟對話方塊(OpenFileDialog)載入需要的檔案。有關程式碼的編寫如下所述：

Dim filename As String

If dlgOpenDigFile.ShowDialog() = DialogResult.OK Then

filename = dlgOpenDigFile.FileName

End If

'載入點陣圖

Dim mybmp As New Bitmap(filename)

' 顯示成果.

PictureBox1.Image = mybmp

PictureBox1.SizeMode = PictureBoxSizeMode.Normal

21.5.3像素處理

點陣圖提供兩種像素的處理方法：(1)擷取像素(GetPixel)，及(2)佈設像素(SetPixel)

兩種方法作為像素運算處理的作業基礎。GetPixel與SetPixel作業均須在BitMap記憶體中處理，運算處理完成後再藉由Form或PictureBox來顯示作業結果，無法直接在Form或PictureBox上作業。如需直接在Form或PictureBox不透過Form或PictureBox則可以藉Window Api來完成。下面之片段程式碼為典型的GetPixel與SetPixel作業方式。

Dim clr As Integer

Dim xmax As Integer

Dim ymax As Integer

Dim x As Integer

Dim y As Integer

' 取得點陣圖及尺寸.

Dim yans As Integer = MsgBox("是否取得點陣圖(*.Bmp)?", MsgBoxStyle.YesNo)

If yans = 7 Then

MsgBox("請載入圖檔後重來")

Exit Sub

End If

Dim mybmp As Bitmap = PictureBox1.Image

xmax = mybmp.Width - 1

ymax = mybmp.Height - 1

' 轉換成灰階圖片.

For y = 0 To ymax

For x = 0 To xmax

With mybmp.GetPixel(x, y) ‘擷取像素

clr = 0.3 * .R + 0.5 * .G + 0.2 * .B

End With

mybmp.SetPixel(x, y, _

Color.FromArgb(255, clr, clr, clr)) ‘鋪設像素

Next x

Next y

' 顯示圖片.

PictureBox1.Image = mybmp

下面的片段程式碼為直接在Form或PictureBox上利用Api函數，直接擷取像素及佈設像素的作業方式。

Private Shared Function GetDC(ByVal hwnd As IntPtr) As IntPtr

End Function

Private Declare Function GetPixel Lib "gdi32" Alias "GetPixel" (ByVal hdc As IntPtr, ByVal X As Int32, ByVal Y As Int32) As Int32

Private Declare Function SetPixel Lib "gdi32" Alias "SetPixel" (ByVal hdc As IntPtr, ByVal X As Int32, ByVal Y As Int32, ByVal crColor As Int32) As Int32

Private Shared Function ReleaseDC(ByVal hWnd As IntPtr, ByVal hDC As IntPtr) As Integer

Dim lngPtcolor As Long

Dim gp1 As Graphics = PictureBox1.CreateGraphics

Dim hdc1 As IntPtr = gp1.GetHdc()

Dim lngsetcolor As Integer

For i As Integer = 0 To PictureBox1.Width - 1

For j As Integer = 0 To PictureBox1.Height - 1

lngPtcolor = GetPixel(hdc1, i, j)

SetPixel(hdc1, i, j, lngPtcolor)

Next j

Next i

ReleaseDC(IntPtr.Zero, hdc1) '將DC 釋放

End sub

VB.NET中可使用Graphics類別的DrawImage方法顯示圖形檔，在不同時間間隔不同的位置顯示同一圖形檔會產生視覺上的動畫效果。DrawImage方法可指定目的繪圖區，也可指定來源圖片的顯示範圍，具備自動縮放功能，會自動將圖片放大或縮小以填充指定的整個繪圖區域，其使用語法有：

DrawImage(Image物件，x,y)

DrawImage(Image物件，Point結構)

DrawImage(Image物件，目的Rectangle結構)

DrawImage(Image物件，x,y，來源Rectangle結構，圖形單位)

DrawImage(Image物件，目的Rectangle結構，來源Rectangle結構，圖形單位)

下面為利用DrawImage方法所製作的簡單動畫小精靈，藉四個有不同的開口橢圓，二個小圓代表小精靈口中小虫及眼睛，利用計時器每100毫秒以改變小精靈位置(x.y值)產生動畫效果。

'首先在Form1類中定義變數，程序螞如下。

Dim iRepeat As Integer

Dim x, y, wid, ht As Integer

Dim angBeg(3) As Integer

Dim angEnd(3) As Integer

Dim gp As Graphics

Dim ncount As Integer = 0

'Form1的Load事件編寫程序螞，設置初始值，程序螞如下所示。

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

gp = PicCanvas.CreateGraphics

x = PicCanvas.Width - 10 : y = 10 : wid = 55 : ht = 50 '開始時小精靈位置

angBeg(0) = 130 '第一個圖的起始角度

angEnd(0) = -250 '第一個圖的結束角度

angBeg(1) = 150 '第二個圖的起始角度

angEnd(1) = -280 '第三個圖的結束角度

angBeg(2) = 180 '第三個圖的起始角度

angEnd(2) = -315 '第三個圖的結束角度

angBeg(3) = 200 '第四個圖的起始角度

angEnd(3) = -350 '第四個圖的結束角度

iRepeat = 0

Timer1.Enabled = False

End Sub

'為Timer控制項的Tick事件編寫程序碼，在不同的時間間隔裏於不會位置繪製不同缺口的扇形，並且一直從右往左迴圈運動直到停止運行

Private Sub Timer1_Tick(ByVal sender As Object, ByVal e As System.EventArgs) Handles Timer1.Tick

gp.Clear(PicCanvas.BackColor)

gp.FillEllipse(Brushes.Red, x + 10, y + 15, 10, 10) '小精靈口中飛行小虫

gp.FillPie(Brushes.Green, x, y, wid, ht, angBeg(iRepeat), angEnd(iRepeat))

gp.FillEllipse(Brushes.White, x + 35, y + 18, 10, 10) '小精靈眼睛

iRepeat = iRepeat + 1

If iRepeat > 3 Then iRepeat = 0

x = x - 10 '變化座標位置

y = y + ncount * 2

If x < 10 Then

x = PicCanvas.Width - 10

ncount = ncount + 1

End If

If y > PicCanvas.Height - 30 Then

y = 10

ncount = 0

End If

End Sub

21.5.4線性轉換

我們在本書第一章就介紹過線性方程組及矩陣的觀念，.您對數學不怎麼感興趣，也沒關係。在GDI+程式中，您可以把它當作是一般物件，並且使用它們的屬性和方法像其他物件一樣。VB .NET提供有Multiply、Rotate、RotateAt、Scale、Shear 和 Translate等矩陣方法。VB .NET用來表示仿射轉換的矩陣第三個資料行(Column)永遠為 (0, 0, 1)，因此在建立 Matrix 物件時，您只需要指定前兩個資料行中的六個數字。使用Matrix物件第一件事就是建立Matrix物件後方能作線性轉換，有時候，在真實的程式世界裡，我們可能需要計算轉換矩陣中各別元素。如下面的片段程式：

Dim myMatrix As Matrix = New Matrix(1, 0, 0, 2, 0, 0) ‘六個數字所代表的矩陣
myMatrix.Scale(2, 2) ‘比例轉換

’建立一個畫圖物件，及一個黑色矩形
Dim Gp as Graphics = PictureBox1.CreateGraphics

Dim Rect As Rectangle = New Rectangle(20, 20, 40, 60)

Gp.DrawRectangle(Pens.Black, Rect)

’以myMatrix為引數，作為矩陣之線性轉換

Gp.MultiplyTransform(myMatrix, MatrixOrder.Append)

Gp.DrawRectangle(Pens.Orange, Rect)

我們必須再考慮座標系統的觀念，在GDI+畫圖作業中，世界系統座標(world coordinates)必須轉換成頁面座標(page coordinates)，然後設備座標(device coordinates)。上述的MultiplyTransform矩陣方法只是對畫圖物件進行轉換而非對矩形作轉換。另一方面，我們必須考慮到，矩陣轉換次序，在一般數學運算A *B與B *A是相等的。但對矩陣之運算，次序是很重要，如下面之運算

gp.TranslateTransform(-70, 35, MatrixOrder.Append)

gp.RotateTransform(30, MatrixOrder.Append)

gp.TranslateTransform(186, 75, MatrixOrder.Append)

gp.ScaleTransform(2.25F, 0.5F, MatrixOrder.Append)

與

gp.TranslateTransform(-70, 35, MatrixOrder.Prepend)

gp.RotateTransform(30, MatrixOrder.Prepend)

gp.TranslateTransform(186, 75, MatrixOrder.Prepend)

gp.ScaleTransform(2.25F, 0.5F, MatrixOrder.Prepend)

運算結果是不一樣的。

　

矩陣轉換有所謂區域轉換及全域轉換兩種，全域轉換會套用至特定Graphics物件繪製的所有項目；相對地，區域轉換只套用至要繪製的特定項目。

如果要建立全域轉換，應先建構Graphics物件，然後管理Transform屬性。Transform 屬性是一個 Matrix 物件，因此它可以存放仿射轉換的任何序列。儲存在Transform屬性的轉換又稱為全局轉換。Graphics類別提供幾個方法，用來建置複合的全局轉換：MultiplyTransform、RotateTransform、ScaleTransform和TranslateTransform。下列範例會繪製兩次橢圓形：一次是在建立全局轉換之前，一次是在建立之後。轉換會先在Y方向縮放0.75個單位，然後在X方向平移40個單位，然後再旋轉45度。

Dim gp As Graphics = PictureBox1.CreateGraphics '建立畫圖物件

gp.DrawEllipse(myPen, 0, 0, 100, 50) '畫橢圓

gp.ScaleTransform(1, 0.75F) '比例縮放

gp.TranslateTransform(40, 0, MatrixOrder.Append) '平移

gp.RotateTransform(45, MatrixOrder.Append) '旋轉

gp.DrawEllipse(myPen, 0, 0, 100, 50) '線性轉換後畫橢圓

區域轉換會套用至要繪製的特定項目，如GraphicsPath物件的Transform方法可用來轉換該路徑的資料點 (Data Point)。下列範例繪製未轉換的矩形和經過旋轉和轉換的路徑(假設沒有全局轉換)。

Dim gp As Graphics = PictureBox1.CreateGraphics '建立畫圖物件

Dim myGraphicsPath As New GraphicsPath '建立畫圖路徑

Dim myMatrix As New Matrix() '建立矩陣物件

gp.DrawRectangle(Pens.Blue, 50, 50, 100, 150)

myGraphicsPath.AddLine(150, 200, 250, 250)

gp.DrawPath(Pens.Green, myGraphicsPath)

myMatrix.Rotate(30)

gp.Transform = myMatrix '繞座標原點旋轉

myGraphicsPath.Transform(myMatrix) '觀察有無加本列後圖形變化

gp.DrawRectangle(Pens.Red, 50, 50, 100, 150)

myGraphicsPath.AddLine(150, 200, 250, 250)

gp.DrawPath(Pens.Gray, myGraphicsPath)

您可以使用全局轉換來改變座標系統，並可使用區域轉換來旋轉和縮放新座標系統所繪製的物件。假設您想要使用一個座標系統，其原點距離工作區左邊緣200像素和工作區頂端100像素處。現在您想使用像素做為度量單位，其x軸指向右方為正，y軸朝上為正(預設座標系統的y軸朝下)，因此您必須在水平軸執行反射。下面為座標反射的矩陣片段程式碼。

Dim gp As Graphics = PictureBox1.CreateGraphics '建立畫圖物件

'全局轉換

Dim myMatrix As New Matrix(1, 0, 0, -1, 0, 0) '反射矩陣係數

gp.Transform = myMatrix '

gp.TranslateTransform(100, 150, MatrixOrder.Append) '平移

ListBox1.Items.Add("反射及平移後矩陣係數myMatrix")

For Each TransformElement As Single In gp.Transform.Elements

ListBox1.Items.Add(TransformElement) ‘輸出轉換矩陣係數

'建立路徑.

Dim myGraphicsPath As New GraphicsPath()

Dim myRectangle As New Rectangle(0, 0, 80, 60)

myGraphicsPath.AddRectangle(myRectangle)

' 填充路徑(反射新座標系統),無區域轉換

Dim mySolidBrush = New SolidBrush(Color.Green)

gp.FillPath(mySolidBrush, myGraphicsPath)

' 在GraphicsPath物件設定區域轉換.

Dim myPathMatrix As New Matrix()

myPathMatrix.Scale(2, 1)

myPathMatrix.Rotate(30, MatrixOrder.Append)

myGraphicsPath.Transform(myPathMatrix)

' 填充路徑(反射新座標系統),有區域轉換.

gp.FillPath(New SolidBrush(Color.Blue), myGraphicsPath)

gp.Transform.Reset() '線性轉換歸零

gp.Dispose()

Dim gp1 As Graphics = PictureBox1.CreateGraphics '建立畫圖物件

gp1.TranslateTransform(100, 150, MatrixOrder.Append) '平移

ListBox1.Items.Add("")

ListBox1.Items.Add("僅平移後矩陣係數myMatrix")

For Each TransformElement As Single In gp1.Transform.Elements

ListBox1.Items.Add(TransformElement) ‘輸出轉換矩陣係數

Dim myGraphicsPath1 As New GraphicsPath()

Dim myRectangle1 As New Rectangle(0, 0, 80, 60)

myGraphicsPath1.AddRectangle(myRectangle1)

' 填充路徑(無反射,原座標系統),無區域轉換

Dim mySolidBrush2 = New SolidBrush(Color.Yellow)

gp1.FillPath(mySolidBrush2, myGraphicsPath) '未反射

gp1.Dispose()

下圖為執行後之成果畫面，圖中黃色為座標未作反射僅平移之原圖形，籃色部份為使用新座標系統且有區域轉換者；綠色部份則為使用新座標系統但無有區域轉換者。

如果需要寫出矩陣資料可以使用類似下列程式碼：

For Each TransformElement As Single In GraphicObj.Transform.Elements

Debug.WriteLine(TransformElement) ‘輸出轉換矩陣係數

21.6橡皮筋線製作

在Vb .0及更早版本，繪製橡皮筋線是相當簡單及直接的，您可以將DrawMode設定等於6(DrawMode=6，即DrawMode=vbInvert)畫一條線，然後在原位置再重畫一次就可以將原來直線塗抹掉。此利用一個像素顏色之反向再反向為原來顏色之觀念。基於某些理由VB .Net並沒有反向模式概念，因此畫橡皮筋線，您需要建立一個Bitmap陣列圖物件(一個虛擬緩衝暫存區)來代表及儲存圖像(image)。在表單(Form)或圖形方塊(PicctureBox)上畫線然後塗抹掉，複製儲存在Bitmap 陣列圖物件中的圖像至表單(圖形方塊)。

MouseDown()程序事件中，其主要工作有兩項：

(1)呼叫副程式SaveSnapshot(儲存快照)儲存變數m_X1、m_Y1、 m_X2及m_Y2的位置座標，SaveSnapshot建立一個新Bitmap陣列圖並用它來建立一個附著於此Bitmap之畫圖物件。為了讓讀者能瞭解電腦實際運作方式，特別將其編寫成比較直接易懂方式，並額外安排LblMDxy1及LblMDxy2兩個標籤控制項分別記錄m_X1、m_Y1及 m_X2、m_Y2座標位置變化。

(2)開始處理程序時，按下滑鼠左鈕時將m_Drawing布林值設定為真(True)，在m_Drawing

=False時，自動跳出MouseDown事件程序。在此也安排Lbldrawing控制項以觀察m_Drawing變化情況。

MouseMove()程序事件，主要功能為：

當user按下滑鼠左鈕並移動滑鼠時，儲存移動新點座標m_X2、m_Y2位置，MouseMove事件把柄(MouseMove event handler)呼叫副程式DrawForm(或DrawPic)以塗抹掉畫在表單(或圖形方塊)上前畫好之直線，然後利用DrawLine方法在表單上(或圖形方塊)畫線(不是Bitmap上直接畫線)，因此Bitmap上並無此直線。下一回User移動滑鼠，MouseMove事件把柄呼叫DrawForm(或DrawPic)，則Bitmap顯示並無此新線。副程式DrawForm(或DrawPic)只用DrawImage將其儲存在Bitmap的已畫好的圖元畫到表單(或圖形方塊)上。

MouseUp()程序事件，主要功能為：

當User放開滑鼠左鈕時，通知電腦m_Drawing已改設定為False，MouseUp事件把柄用儲存在Bitmap中的以DrawLine方法所畫出最後一條直線在儲存的bitmap上，再呼叫DrawForm 顯示有新線的bitmap。

Pic_Paint()事件程序中Pic_Paint event handle，因為VB .NET沒有AutoRedraw屬性，因此user想在表單或圖形方塊被全部或部份覆蓋再恢復出露時，User必須自行處理，此Pic_Paint event handler呼叫DrawPictureBox顯示儲存在bitmap上點陣圖。

' 畫新線時m_Drawing 布林值為真.

Private m_Drawing As Boolean

' 暫存緩衝區以抹掉橡皮筋線.

Private m_BufferBitmap As Bitmap ‘暫存緩衝區Bitmap

Private m_BufferGraphics As Graphics‘暫存緩衝區畫圖物件

' 滑鼠位置座標

Private m_X1 As Integer

Private m_Y1 As Integer

Private m_X2 As Integer

Private m_Y2 As Integer

'開始畫橡皮筋線

Private Sub Form1_MouseDown(ByVal sender As Object, ByVal e _

    As System.Windows.Forms.MouseEventArgs) Handles _

    MyBase.MouseDown

    ' 如果非使用到滑鼠左鈕就退出.

    If e.Button <> MouseButtons.Left Then Exit Sub

    m_Drawing = True   ‘開始畫圖

    ' 儲存表單快照

    SaveSnapshot() ‘儲存快照

    ' 儲存滑鼠目前位置

    m_X1 = e.X

      m_Y1 = e.Y

m_X2 = e.X

    m_Y2 = e.Y

End Sub

' 繼續繪製橡皮筋線

Private Sub Form1_MouseMove(ByVal sender As Object, ByVal e _

    As System.Windows.Forms.MouseEventArgs) Handles _

    MyBase.MouseMove

    If Not m_Drawing Then Exit Sub ‘m_Drawing=false跳出

    ' 儲存新點

    m_X2 = e.X

    m_Y2 = e.Y

    ' 塗抹掉前一條線Erase the previous line.

    DrawForm(Me.CreateGraphics())

    ' 在表單上直接繪製新線Draw the new line directly on the form.

    Me.CreateGraphics().DrawLine( _

        Pens.Gray, m_X1, m_Y1, m_X2, m_Y2)

End Sub

'完成新直線 Finish drawing the new line.

Private Sub Form1_MouseUp(ByVal sender As Object, ByVal e _

    As System.Windows.Forms.MouseEventArgs) Handles _

    MyBase.MouseUp

    ‘m_Drawing=Fales退出' Do nothing if we're not drawing.

    If Not m_Drawing Then Exit Sub ‘m_Drawing=Fales退出

    m_Drawing = False

    ' 儲存新點Save the new point.

    m_X2 = e.X

    m_Y2 = e.Y

    ' 在緩衝區繪永久直線Draw the new line permanently on the buffer.

    m_BufferGraphics.DrawLine( _

        Pens.Blue, m_X1, m_Y1, m_X2, m_Y2)

    ' 在表單上重繪新線Redraw to show the new line.

    DrawForm(Me.CreateGraphics())

End Sub

' 重繪表單Redraw the form.

Private Sub Form1_Paint(ByVal sender As Object, ByVal e As _

    System.Windows.Forms.PaintEventArgs) Handles _

    MyBase.Paint

    DrawForm(e.Graphics)

End Sub

' 重繪已儲存緩衝區圖元Redraw the saved buffer.

Private Sub DrawForm(ByVal gr As Graphics)

    If Not (m_BufferBitmap Is Nothing) Then _

        gr.DrawImage(m_BufferBitmap, 0, 0)

End Sub

Private Sub SaveSnapshot()

    Dim new_bitmap As Bitmap

    ' 建立等於表單尺寸的點陣圖Make a new bitmap that fits the form.

    new_bitmap = New Bitmap(Me.Size.Width, Me.Size.Height, _

        Me.CreateGraphics())

    m_BufferGraphics = Graphics.FromImage(new_bitmap)

    ' 清理新點陣圖Clear the new bitmap.

    m_BufferGraphics.Clear(Me.BackColor)

    ' 複製現存點陣圖內容到新點陣圖Copy the existing bitmap's contents into

    ' the new bitmap.

    If Not (m_BufferBitmap Is Nothing) Then

        m_BufferGraphics.DrawImage(m_BufferBitmap, 0, 0)

    End If

    ' 儲存新點陣圖及畫圖物件Save the new bitmap and graphics objects.

    m_BufferBitmap = new_bitmap

End Sub

VB_VB NET: chday169

上次修改此網站的日期： 2018年12月02日